From 858a4a31a251d0eab21dffb96776aca007dafb07 Mon Sep 17 00:00:00 2001
From: Chloe Kudryavtsev <toast@toast.cafe>
Date: Fri, 14 Feb 2020 19:11:04 -0500
Subject: Squashed 'dot_local/share/toasty/' content from commit aee4da7

git-subtree-dir: dot_local/share/toasty
git-subtree-split: aee4da752bdb07b0524bb8803ead46d4093fa57f
---
 zshrc | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 zshrc

(limited to 'zshrc')

diff --git a/zshrc b/zshrc
new file mode 100644
index 0000000..33fcbb6
--- /dev/null
+++ b/zshrc
@@ -0,0 +1,56 @@
+print -Pv zrc %N  # get current file location, store it in $zrc
+zrc="$zrc:A"      # resolve $zrc (assume path) to its absolute location
+zshd="${zrc:h}"
+
+: "${zd:=$HOME/.zsh}"
+
+# spath -> autosource path, ala plugins
+# apath -> sourceall path, for .d dirs
+typeset -T SPATH spath
+typeset -T APATH apath
+
+# default values
+spath=(
+    "$zd/plugins"
+    "$zshd/plugins"
+)
+apath=(
+    "$zshd/source"
+    "$zd/source"
+)
+
+# user stuff comes first
+# completions come after the functions they complete
+fpath+=(
+    "$zd/functions"
+    "$zd/completions"
+    "$zd/prompts"
+    "$zshd/functions"
+    "$zshd/completions"
+    "$zshd/prompts"
+)
+
+# sourced before sourcealling
+# should be the location to edit fpath/apath/spath
+[[ -f "$zd/pre" ]] && . "$zd/pre"
+
+# allow digest drop-in
+if [[ -d "$zd/digests" ]]; then
+    local f=
+    for f in $zd/digests/*.zwc(N); do
+        fpath+=( "$f" )
+        autoload -w "$f"
+    done
+fi
+
+autoload sourceall
+sourceall zsh # source every .zsh file in every $apath[@] directory
+
+# local zshrc
+[[ -f "$zd/zshrc.local" ]] && . "$zd/zshrc.local"
+
+# LITERALLY THE VERY LAST THING WE DO IS COMPINIT PLS DUN DO IT URSELF
+autoload -Uz compinit
+compinit
+
+# vim: ft=zsh
-- 
cgit v1.2.3